SIMULATE 2

demand FUNCTION x$price,C
50 100
70 80
90 60
110 45
130 35
150 30
170 25
! Price of 1 sofa
HELP INPUT,X$price
! The number of frames bought each time
HELP INPUT,X$nFrame
! The time between production start of a new sofa
HELP INPUT,X$tSofa
! Re-ordering levels for frames
HELP INPUT,X$ROL
LET X$cash=300
LET X$maxloa=300
LET X$ucost=17+8+20+130/x$nFrame
stock CAPACITY 20
frames CAPACITY 15
QTABLE queue,0,7,20
	GENERATE fn$xpdis*360/fn$demand	! Risthein & Aile
	IF stock=NE,purch
	ARRIVE queue
	WAITIF stock=E
	DEPART queue
purch	LEAVE stock,1
	LET+ x$accrec,x$price
	LET+ x$income,x$price
	LET+ x$CGS,x$ucost
	ADVANCE 45*fn$rlng3
	LET+ x$cash,x$price
	LET- x$accrec,x$price
	HELP GRAPHC,CL,x$cash
	TERMINATE 

	GENERATE 7,,0
	IF s$frames>=x$ROL,die
	IF order=U,die
	SEIZE order
	ADVANCE 35+7*fn$snorm
	ENTER frames,x$nFrame
	RELEASE order
	LET x$pay=20*x$nFrame+130
	LET+ x$accdue,x$pay
	ADVANCE 30
	LET- x$accdue,x$pay
	LET- x$cash,x$pay
	HELP GRAPHC,CL,x$cash
	IF x$cash<0,loan
die	TERMINATE 

	GENERATE x$tSofa,,0
	IF frames=E,die2
	LEAVE frames,1
	LET+ x$work,1
	ADVANCE 28,14
	WAITIF stock=F
	LET- x$work,1
	ENTER stock,1
	LET- x$cash,25
	HELP GRAPHC,CL,x$cash
	IF x$cash<0,loan
die2	TERMINATE 
loan	LET+ x$loan,-x$cash
	IF x$loan+x$inter>x$maxloa,bankru
	LET x$cash=0
	HELP GRAPHC,CL,x$cash
	TERMINATE 
bankru	PRINT 'Bankrupcy!'
	TERMINATE 4

	GENERATE 90
	LET+ x$quart,1
	PRINT 'Quarter ',x$quart
	PRINT 'INCOME STATEMENT'
	PRINT '----------------------------------'
	PRINT 'Sales                   ',x$income
	PRINT 'Cost of Goods Sold      ',-x$CGS
	LET x$inter=x$loan*0.018	! interest
	PRINT 'Interest Cost           ',-x$inter
	LET x$costs=x$CGS+x$inter
	PRINT 'Total costs             ',-x$costs
	LET+ x$loan,x$inter
	LET x$profit=x$income-x$CGS-x$inter
	PRINT '----------------------------------'
	PRINT 'Profit                  ',x$profit
	PRINT '=================================='
	PRINT 'ASSETS'
	PRINT 'Cash                    ',x$cash
	PRINT 'Accounts Receivable     ',x$accrec
	LET x$stockv=s$stock*x$ucost+(s$frames+x$work)*(20+130/x$nFrame)
	PRINT 'Inventories             ',x$stockv
	LET x$assets=x$cash+x$accrec+x$stockv
	PRINT 'Total assets             ',x$assets
	PRINT '----------------------------------'
	PRINT 'LIABILITIES'
	PRINT 'Accounts due            ',x$accdue
	PRINT 'Loan                    ',x$loan
	LET x$liab=x$loan+x$accdue
	PRINT 'Total liabilities       ',x$liab
	PRINT '----------------------------------'
	LET x$equity=x$assets-x$liab
	PRINT 'Equity                  ',x$equity
	PRINT '=================================='
	IF x$equity<0,bankru
	LET x$income=0
	LET x$CGS=0
	TERMINATE 1

	GENERATE ,,,1
	HELP GRAPHC,CL,x$cash
	TERMINATE 

START 4
END